3DEXPERIENCE | 3DSwym GEOVIA User Community
Log in
Surpac Tip - TCL/SCL macro series (5 of 10)

AC

Surpac Tip - TCL/SCL macro series (5 of 10)

Part 5 – Looping over data in a layer and extracting information from Dfields.  i.e. d1, d2 or d99

SCL provides a number of excellent functions to create, add, import and manipulate layers.  There is also great reference material in the Surpac->Help menu.  My aim in this series is to introduce some of these features in more layman’s terms.  Some knowledge of how macro’s work with variables and commands will certainly be helpful but is not essential.

In the following tip;

  • My comments in the code blocks will have a # in front of them. They are also in bold and italicized. 

  • If you would like to test this code in Surpac, the entire code block (Including previous parts 1, 2, 3 and 4) has been added to the end of the tip.  Copy it into any text editor and save it with a .tcl extension to use it in Surpac.  The final result will look similar (but not the same due to styles and the choices you make when using the macro) as the screen capture below.

 

The "puts" command will print the series number to the message window plus other information about what this macro will do.

#Part 5
puts ""
puts "Part 5 - Using Scl to loop over all points in a layer"

Using SCL commands, get a handle to the viewport, then the layer, then the strings in the layer.  Essentially, we are working our way down the data heirarchy.  (Viewport->Layer->Strings->Segments->Points)

# Get a handle to the viewport
SclGetActiveViewport vh
# Using the viewport handle, get a handle to the SWA (layer)
\$vh SclGetActiveLayer SwaH
# Using the handle to the SWA, get a handle to all the strings in the layer
\$SwaH SclGetStrings StrsH

Test to see if there are any strings in the active layer.  If there aren't any strings in the active layer, we can use an if statement to terminate the script and output information to the message window explaining what is required.  In this case telling the user that there are no strings in the active layer.

# Count how many strings are in the active layer
set strQuantity [\$StrsH SclCountItems]
# If there aren't any strings then write a message to the user and stop the macro using the "return" command.
if {\$strQuantity <= 0} {
  puts "No strings in active layer."
  return
}

Using the handle to all the strings in the active layer (\$StrsH) setup an iterator to loop over each string, one by one.

# Setup a string iterator based on the handle to the strings in "\$StrsH"
\$StrsH SclIterateFirst StringsIterator
# While there are strings to iterate, keep going
while {[\$StringsIterator SclIterateNext StringHandle] == \$SCL_TRUE} {
# Use SclGetId to work out the string number and print it to the message window
  puts "String number = [\$StringHandle SclGetId]"

Using the handle to the first string in the active layer (\$StringHandle) setup an iterator to loop over each segment, one by one.

# Setup a segment iterator based on the handle to the string in "\$StringHandle"
\$StringHandle SclIterateFirst StringIterator
# While there are segments to iterate over in the current string, keep going
  while {[\$StringIterator SclIterateNext SegmentHandle] ==  \$SCL_TRUE} {
  # Remember, we add one to the segment number because segments work from an index position which starts at zero.
    puts "Segment number = [expr [\$SegmentHandle SclGetId]+1]"

Using the handle to the first segment of the first string in the active layer (\$SegmentHandle) setup an iterator to loop over each point, one by one.  As points are the lowest part of the data heirarchy, we can now extract data from each point.

    # Setup a point iterator based on the handle to the segment in "\$SegmentHandle"
    \$SegmentHandle SclIterateFirst SegmentIterator
    set PointCount 1
    # While there are points in the segment to iterate over, keep going.
    while {[\$SegmentIterator SclIterateNext PointHandle] == \$SCL_TRUE} {

Using the handle to each point (\$PointHandle), use SclGetValueByName to extract any relevant data from the point that we need. Note, you can extract x, y and z of each point as well as any dfield such as d1 shown below or even all dfields as a list of data by using "desc".  As an example, if d1=bread, d2=cheese and d3=meat, using desc to get the data would retrieve "bread cheese meat" in a list variable.  We will cover lists in an upcoming post in this series (Part 7)

      set x [\$PointHandle SclGetValueByName x]
      set y [\$PointHandle SclGetValueByName y]
      set z [\$PointHandle SclGetValueByName z]
      set d1 [\$PointHandle SclGetValueByName d1]
      puts "Point \$PointCount X = \$x, Y = \$y, Z = \$z, D1 = \$d1"
      incr PointCount

The brackets below close off the three "while" loops above. i.e. Looping strings, looping segments and looping points.

    };# End of looping points for the current segment
  };# End of looping segments for the current string
};# End of looping strings in the current layer
puts "You can also iterate backwards by changing SclIterateFirst for SclIterateLast"
puts "AND SclIterateNext for SclIteratePrev.  There are several reasons for needing to do this especially when deleting strings"

Below is how the looping code looks as an entire code block.  The only difference between the code block below and the code block above is that the example below starts at the last string in the file (SclIterateLast) and loops backwards (SclIteratePrev).  This includes looping from the last point on each segment to the first point.  This is important functionality, especially when deleting data using looping structures.

\$StrsH SclIterateLast StringsIterator
while {[\$StringsIterator SclIteratePrev StringHandle] == \$SCL_TRUE} {
  puts "String number = [\$StringHandle SclGetId]"
  \$StringHandle SclIterateLast StringIterator
  while {[\$StringIterator SclIteratePrev SegmentHandle] ==  \$SCL_TRUE} {
    puts "Segment number = [expr [\$SegmentHandle SclGetId]+1]"
    \$SegmentHandle SclIterateLast SegmentIterator
    set PointCount 1
    while {[\$SegmentIterator SclIteratePrev PointHandle] == \$SCL_TRUE} {
      set x [\$PointHandle SclGetValueByName x]
      set y [\$PointHandle SclGetValueByName y]
      set z [\$PointHandle SclGetValueByName z]
      puts "Point \$PointCount X = \$x, Y = \$y, Z = \$z"
      incr PointCount
    }
  }
}

Here are some other things that can be done with this simple looping code.

  1. Write points to a csv file
  2. Modify the z value of points in a segment
  3. Write points inside a boundary to a new layer

  4. Identify points by inquiring their dfields.

     

Entire code block - Parts 1 to 5 - Copy into text editor and run in Surpac with .tcl extension 

####### PART 1 #######
# Get a reference to the active viewport (You can have more than one) store it in reference variable "vh"
SclGetActiveViewport vh
# Using the "vh" reference, get the active layer and store the reference in the "initialSwa" variable
\$vh SclGetActiveLayer initialSwa
# Extract the layer name into the layerName variable using the SCL command "SclGetId"
set layerName [\$initialSwa SclGetId]
# Print the layer name to the message window
puts "Layer name is \$layerName"

# Create a layer called design that can be manipulated/inquired with the "designSwa" reference variable
SclCreateSwa designSwa "design"

# Use the SclAdd function to add the layer into the layer panel
sclGraphicsLayers SclAdd \$designSwa \$vh

# Using the reference to "designSwa", create a reference variable "designStr" and make the string number 8
\$designSwa SclCreateString designStr 8


# Using the reference to the "designStr" create a reference variable "designSeg" and count how many items (i.e. segments) already
# exist for string 8. If there are 5 existing segments in string number 8, [\$designStr SclCountItems] will return a value of 5.
# 5 will become the new segment number.  Now, why doesn't this clash with the existing segments if there are already 5 of them?
# This is because the segments are stored as an index position which starts at zero. i.e. segment 1 = index 0, segment 2 = index 1
# ... segment 5 = index 4 and so on.
# All of this to say that when we count how many items are in string 8, the number returned will work as the next index position
# which is what the "SclCreateSegment" function requires. So if I write it manually it becomes
# \$designStr SclCreateSegment designSeg 5 
\$designStr SclCreateSegment designSeg [\$designStr SclCountItems]

# Using the reference variable "designSeg" count how many points there are and add this one to the end
\$designSeg SclCreatePoint designPnt [\$designSeg SclCountItems]
\$designPnt SclSetValueByName X 10
\$designPnt SclSetValueByName Y 10
\$designPnt SclSetValueByName Z 10
\$designPnt SclSetValueByName d1 "Testing SCL layer commands"

# Using the reference variable "designSeg" count how many points there are and add this one to the end
\$designSeg SclCreatePoint designPnt [\$designSeg SclCountItems]
\$designPnt SclSetValueByName X 10
\$designPnt SclSetValueByName Y 20
\$designPnt SclSetValueByName Z 10

# Using the reference variable "designSeg" count how many points there are and add this one to the end
\$designSeg SclCreatePoint designPnt [\$designSeg SclCountItems]
\$designPnt SclSetValueByName X 20
\$designPnt SclSetValueByName Y 20
\$designPnt SclSetValueByName Z 10

# Using the reference variable "designSeg" count how many points there are and add this one to the end
\$designSeg SclCreatePoint designPnt [\$designSeg SclCountItems]
\$designPnt SclSetValueByName X 20
\$designPnt SclSetValueByName Y 10
\$designPnt SclSetValueByName Z 10

# To close the shape, make the x,y and z the same as the first point.
\$designSeg SclCreatePoint designPnt [\$designSeg SclCountItems]
\$designPnt SclSetValueByName X 10
\$designPnt SclSetValueByName Y 10
\$designPnt SclSetValueByName Z 10

# Using the reference to the design layer (designSwa), use the command "SclDraw" to draw everything in the design layer.
\$designSwa SclDraw
SclFunction "ZOOM ALL" {}

# Now, the active layer is still the initial layer that was active when the macro was first run.  Let's make it the design layer
\$vh SclSetActiveLayer \$designSwa

####### PART 2 #######

#Create a layer called square_2 that can be manipulated/inquired with the "square2Swa" reference variable
SclCreateSwa square2Swa "square_2" 
sclGraphicsLayers SclAdd \$square2Swa \$vh
# Using the reference to "square2Swa", create a reference variable "square2Str" and make the string number 6
\$square2Swa SclCreateString square2Str 6
# Create a new segment.  See details from part 1 about how this works.
\$square2Str SclCreateSegment square2Seg [\$square2Str SclCountItems]

# Procedure is called "newPoint" and takes 4 parameters.  
# 1. The segment reference 2. The X coord, 3. The Y coord and 4. the Z coord
proc newPoint {segHandle x y z} {
  # The rest of the code is exactly the same as what we did in part one when creating a new point
  # The only difference being that we are using variables i.e. \$x that are input when the procedure is called.
  \$segHandle SclCreatePoint pntHandle [\$segHandle SclCountItems]
  \$pntHandle SclSetValueByName X \$x
  \$pntHandle SclSetValueByName Y \$y
  \$pntHandle SclSetValueByName Z \$z
  return \$pntHandle
}

newPoint \$square2Seg 11 11 10;# First point, note that we are using square2seg as the segment reference
newPoint \$square2Seg 11 19 10
newPoint \$square2Seg 19 19 10
newPoint \$square2Seg 19 11 10
newPoint \$square2Seg 11 11 10;# Closing point is same as first point

# Create a layer called square_3 that can be manipulated/inquired with the "square3Swa" reference variable
SclCreateSwa square3Swa "square_3"
sclGraphicsLayers SclAdd \$square3Swa \$vh
# Using the reference to "square3Swa", create a reference variable "square3Str" and make the string number 9
\$square3Swa SclCreateString square3Str 9
# See details from part 1 about how SclCreateSegment works.
\$square3Str SclCreateSegment square3Seg [\$square3Str SclCountItems]

newPoint \$square3Seg 13 13 10;# First point, note that we are using square3seg as the segment reference
newPoint \$square3Seg 13 17 10
newPoint \$square3Seg 17 17 10
newPoint \$square3Seg 17 13 10
newPoint \$square3Seg 13 13 10;# Closing point is same as first point

\$square2Str SclDraw
\$square3Str SclDraw "style=ssi_method=line,HGS_color=line=red,HGS_line_weight=2"

####### PART 3 #######

puts ""
puts "Part 3 - layer iteration and finding the layer you want. Plus, creating a small GUIDO form."

# Get a handle to the active viewport and store it in reference variable "vh"
SclGetActiveViewport vh
# Use sclGraphicsLayers command with SclIterateFirst command to setup a layer iterator
sclGraphicsLayers SclIterateFirst Iterator
# Using a TCL while loop, keep iterating over the layers until there are no more to iterate over. 
while {[\$Iterator SclIterateNext SwaHandle] == \$SCL_TRUE} {
  # Write the layer name to the message window by inquiring the SwaHandle reference variable using the SclGetId command.
  puts "Layer name is [\$SwaHandle SclGetId]"
  # store the layername into a variable called "layerName"
  set layerName [\$SwaHandle SclGetId]
  # Don't store the main graphics layer into the list of selectable layers as it may be empty.
  if {\$layerName != "main graphics layer"} {
    # Append the layerName into a list called layerList.  TCL lists are simple.  Just imagine a shopping list.
    lappend layerList \$layerName
  }
}

puts "Layers added to a list... Click in Graphics to continue"
SclPause

# Form definition start here.  Details of the form are stored in the "layerSelection" variable.
set layerSelection {
#GuidoForm container has two switches, the label and default_buttons switch.   
  GuidoForm form {
    -label "Select Layer"
    -default_buttons
    
    GuidoComboBox layer {
      -label "Layer"
      -width 15
      -exclusive true
      -default "design"
    }
  }
};# Form definition ends here.

# Use the SclCreateGuidoForm command to compile the form into a variable called "formH"
SclCreateGuidoForm formH \$layerSelection {
  # This populates the combobox with all the layers in the layerList variable
  set layer.setValues \$layerList
}
\$formH SclRun {}

if {"\$_status" != "apply"} {
  puts "Macro cancelled"
  # Normally you would stop the macro if someone pressed cancel but in our example we press on.  Just unhash return for normal function.  "return" is another TCL command that in this instance will stop the macro.
  #return
}

puts "You have selected the \"\$layer\" layer"

sclGraphicsLayers SclIterateFirst Iterator
# ourSwa is the reference variable that we can use when setting the active layer
while {[\$Iterator SclIterateNext ourSwa] == \$SCL_TRUE} {
  # store the layername into a variable called "layerName"
  set layerName [\$ourSwa SclGetId]
  # Check to see if the current layer stored in \$layerName is the one selected which is stored in \$layer variable.
  if {\$layerName == \$layer} {
    puts "Active layer is now \$layer.  Check the \"layers\" pane to see if this is true."
    # If we find the required layer, use the SclSetActiveLayer command to change the active layer referenced by \$SwaHandle
    \$vh SclSetActiveLayer \$ourSwa
    puts "Click in graphics once layer is confirmed."
    SclPause
    # no need to search once we have found the layer we are after.  Break will exit the while loop.
    break
  }
}

puts "End of part 3"

####### PART 4 #######

puts ""
puts "Part 4 - Saving a layer then recalling data into a created layer before modifying."
#Saving a layer can be done with a normal recorded "Save Layer" or "Save File" function however SCL provides a way to do it as well.

#Depending on which layer you chose in part 3 will depend on which layer will now be saved.

# This will get the date into a format that the string file header can use
set today [clock format [clock seconds] -format "%d %b %Y"]

#Options variable is a set of parameters separated by the | symbol. Some of the options are styles, binary or text and string range.
set options "header=\$layer, \$today, Test of SclSwaSaveStringFile, ssi_styles:styles.ssi|axis=0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0|binary=off"

# This is the line of code that will save a string file with your included options.
\$ourSwa SclSwaSaveStringFile \$layer.str "\$options"

#Let's assume we have saved the data we want and need to exit graphics to start another project.
SclFunction "EXIT GRAPHICS" {}

#Now, let's recall your saved string file into a new layer we will call new_design
# Get a reference to the active viewport (You can have more than one) store it in reference variable "vh"
SclGetActiveViewport vh
# Create a layer called new_design that can be manipulated/inquired with the "newDesignSwa" reference variable
SclCreateSwa newDesignSwa "new_design"
# Add the new_design layer into the layers pane so it is visible
sclGraphicsLayers SclAdd \$newDesignSwa \$vh
# Everything in "" is an option.  The option to "load draw styles" will ensure the styles file is used.
\$newDesignSwa SclSwaOpenFile \$layer.str "load draw styles"

# Make the "new_design" layer active.
\$vh SclSetActiveLayer \$newDesignSwa

# Get a handle to all the strings in the new_design layer
\$newDesignSwa SclGetStrings newDesignStrs
# Draw all the strings in graphics
\$newDesignStrs SclDraw

# Whenever you bring data into a layer, you'll generally need to zoom all to see it.
SclFunction "ZOOM ALL" {}

# Now, lets say we wanted to edit a point in the layer to a known coordinate. We first need to get a "handle" to the point.
# We will use "SclSelectPoint" to achieve this.  This is a very versatile function that I'll cover in a later QA doco.
# There are many options for editing this point however for this QA I will just move the point 1m East for every click on the point.
# To do this we need to put the command in a while loop.
while {1} {

  # Note pointMod below.  This is the reference variable that gives me complete access to this point and all data attached to it.  
  # Note also that the coordinates of the point are stored in the x, y and z variables below as well.
  set status [SclSelectPoint pointMod "Click a point to move by 1m East. Press Esc to continue." layerName strNum segNum pntNum x y z desc]
  
  # Using the handle we have to the point in reference variable "pointMod" get a handle to the segment it resides in.
  \$pointMod SclGetParent segMod 
  
  if {\$status != "\$SCL_OK"} {
     puts "Finished moving points"
     break
  }
  # Add 1m to the current x value
  \$pointMod SclSetValueByName x [expr \$x+1]

  \$segMod SclErase
  # Using the handle to the segment, draw the updated coords on the screen.
  \$segMod SclDraw
}

puts "End of part 4"

# At this point you could exit or save the modifications. We will leave the modified layer in graphics ready for Part 5 of this series.

# Part 5 will cover how to use SCL to loop over all points in a layer.

####### PART 5 #######

puts ""
puts "Part 5 - Using Scl to loop over all points in a layer"


# Get a handle to the viewport
SclGetActiveViewport vh
# Using the viewport handle, get a handle to the SWA (layer)
\$vh SclGetActiveLayer SwaH
# Using the handle to the SWA, get a handle to all the strings in the layer
\$SwaH SclGetStrings StrsH
# Count how many strings are in the active layer
set strQuantity [\$StrsH SclCountItems]

# If there aren't any strings then write a message to the user and stop the macro using the "return" command.
if {\$strQuantity <= 0} {
  puts "No strings in active layer."
  return
}

# Setup a string iterator based on the handle to the strings in "\$StrsH"
\$StrsH SclIterateFirst StringsIterator
#While there are strings to iterate, keep going
while {[\$StringsIterator SclIterateNext StringHandle] == \$SCL_TRUE} {
#Use SclGetId to work out the string number and print it to the message window
  puts "String number = [\$StringHandle SclGetId]"
  # Setup a segment iterator based on the handle to the string in "\$StringHandle"
  \$StringHandle SclIterateFirst StringIterator
  # While there are segments to iterate over in the current string, keep going
  while {[\$StringIterator SclIterateNext SegmentHandle] ==  \$SCL_TRUE} {
  #Remember, we add one to the segment number because segments work from an index position which starts at zero.
    puts "Segment number = [expr [\$SegmentHandle SclGetId]+1]"
    # Setup a point iterator based on the handle to the segment in "\$SegmentHandle"
    \$SegmentHandle SclIterateFirst SegmentIterator
    set PointCount 1
    # While there are points in the segment to iterate over, keep going.
    while {[\$SegmentIterator SclIterateNext PointHandle] == \$SCL_TRUE} {
      set x [\$PointHandle SclGetValueByName x]
      set y [\$PointHandle SclGetValueByName y]
      set z [\$PointHandle SclGetValueByName z]
      set d1 [\$PointHandle SclGetValueByName d1]
      puts "Point \$PointCount X = \$x, Y = \$y, Z = \$z, D1 = \$d1"
      incr PointCount
    }
  }
}

puts "You can also iterate backwards by changing SclIterateFirst for SclIterateLast"
puts "AND SclIterateNext for SclIteratePrev.  There are several reasons for needing to do this especially when deleting strings"

\$StrsH SclIterateLast StringsIterator
while {[\$StringsIterator SclIteratePrev StringHandle] == \$SCL_TRUE} {
  puts "String number = [\$StringHandle SclGetId]"
  \$StringHandle SclIterateLast StringIterator
  while {[\$StringIterator SclIteratePrev SegmentHandle] ==  \$SCL_TRUE} {
    puts "Segment number = [expr [\$SegmentHandle SclGetId]+1]"
    \$SegmentHandle SclIterateLast SegmentIterator
    set PointCount 1
    while {[\$SegmentIterator SclIteratePrev PointHandle] == \$SCL_TRUE} {
      set x [\$PointHandle SclGetValueByName x]
      set y [\$PointHandle SclGetValueByName y]
      set z [\$PointHandle SclGetValueByName z]
      puts "Point \$PointCount X = \$x, Y = \$y, Z = \$z"
      incr PointCount
    }
  }
}

#There are many things that can be done with this simple looping code.
#1. Write points to a csv file
#2. Modify the z value of points in a segment
#3. Write points inside a boundary to a new layer
#4. Identify points by inquiring there dfields.

puts ""
puts "End of part 5"

 

More Tips: 

   

 

Surpac Product Tips Macros TCL/SCL 

About 3DEXPERIENCE Platform Terms Of Use Privacy Policy Cookies